!******************************************************************************!
! Test that both '0' and 'false' mean false & both '1' and 'true' mean true
!
! Note: visibility is set, but currently unused by LayerWMS
!       extrude is set and used, but it hard to tell any difference
!
! @bug      NXM-3701: true and false are valid fill values LayerKML
! @author:  Jeanette McCall
! @since:   4.0.0 
!******************************************************************************!
startmacro
  switch INTERACTIVE interAct GET DEF=TRUE  SDEF=TRUE  ! for normal interactive test(s)
  switch BASELINE    baseline GET DEF=FALSE SDEF=TRUE  ! for defects or more obscure test case(s)

  call setDatDir

  if interAct then
    set instructions "Both plots should look the same\n&
                      Red outline KML shape should NOT be filled\n&
                      Other KML shapes should be filled\n\n\n&
                      *******************************\n\n&
                      Note: KML values for true and false are\n\n               &
                                     TRUE    FALSE\n&
                      left  plot:     '0'     '1' \n&
                      right plot:   'true'  'false'"

    pipe on
      panel/msgid=MAIN/setup/controls=gc
      gcontrol label macro "Test MACRO"
      gcontrol menu  main "Exit with Status =" "PASS,FAIL" TABLE={ItemColors={PASS="GREEN",FAIL="RED"}} /tleft

      gcontrol text  idtext "Instructions" instructions 24 16 /title

      plot/id=plota ^{datDir}.world.prm|&
           nxm.sys.test.test5000_cones.prm{LAYER={FLAGS=+fillCones}}|&
           nxm.sys.test.kmlPolyFillTest.kml

      plot/id=plotb ^{datDir}.world.prm|&
           nxm.sys.test.test5000_cones.prm{LAYER={FLAGS=+fillCones}}|&
           nxm.sys.test.kmlPolyFillTestTrueFalse.kml

    pipe off

  endif
endmacro

!******************************************************************************!
! Main process message for this macro. Should be right after the ENDMACRO.
!******************************************************************************!
procedure processMessage m:msg
  if msg.name eqs "MAIN" then
    assert/text="^reg.main.name: User indicated tests" msg.data eqss "PASS"
    pipe stop
  elseif msg.name eqs "ZOOM"  then
    message sendw id=plota name=ZOOM data={xmin=167.7149123,xmax=167.7154124,ymin=41.2859,ymax=41.285500}
  elseif msg.name eqs "ZOOM2"  then
    message sendw id=plota name=ZOOM data={xmin=158.702,xmax=158.70208,ymin=33.6478,ymax=33.647720}
  else
    say "Unhandled message name: ^msg.name from fid: ^msg.fid data: ^msg.data"
  endif
return

!******************************************************************************!
! If an unexpected exception is caught, mark test as failed, unless it is expected
!******************************************************************************!
procedure processException m:emsg
  if expectedException REXISTS then
    assert/text="^reg.main.name: Expected ERROR starts with: ^{expectedException}" expectedException EQSS emsg.data.message
    remove expectedException
  else
    assert/text="^reg.main.name: Caught unexpected exception ^{emsg.data}" "FALSE" isTrue
    if "Trace" SUBS ENV.DEBUG then invoke ,, emsg.data.printStackTrace()
  endif
return

!******************************************************************************!
! Set the dat directory
!******************************************************************************!
procedure setDatDir
  invoke nxmMajor env.nmversion.subString(0,1)
  invoke major java.lang.Integer.valueOf(nxmMajor)
  if major GE 4 then
    invoke s:datDir           nxm.sys.test.DatLocator.getDatDirLocation()
    invoke s:datDirSlash      nxm.sys.test.DatLocator.getDatDirSlashLocation()
    invoke z:sysDatFull       nxm.sys.test.DatLocator.sysDatFull()
    invoke z:sysTestDatExists nxm.sys.test.DatLocator.sysTestDatExists()
  else
    set s:datDir           "nxm.sys.dat"
    set s:datDirSlash      "nxm/sys/dat"
    set z:sysDatFull       true
    set z:sysTestDatExists false
  endif
return
