!******************************************************************************!
! Test for resizing a GPanel after popping it's component
!
! @bug      42 UnPopped MAP area needs to disappear
! @author:  J Bauer
!******************************************************************************!
startmacro
  switch INTERACTIVE interAct GET DEF=TRUE  SDEF=TRUE  ! for normal interactive test(s)
  switch BASELINE    baseline GET DEF=FALSE SDEF=TRUE  ! for defects or more obscure test case(s)

  call setDatDir

  if interAct then
    set instructions "You should see the map of the world plotted on a GPanel.\n\n &
                      Click the button or Press CTRL+P on the plot to POP the PLOT off the GPanel.\n\n &
                      The GPanel should disappear (the PUSH/POP button below it should move up).\n\n &
                      Click the PUSH button or press CTRL+P again to PUSH the plot back onto the GPanel.\n\n &
                      The GPanel should display the PLOT identical to the initial state with the PUSH/POP button below it."

    pipe on
      panel/msgid=MAIN/setup/controls=gc
      gcontrol label macro "Test MACRO"
      gcontrol menu  main "Exit with Status =" "PASS,FAIL" TABLE={ItemColors={PASS="GREEN",FAIL="RED"}} /tleft

      gcontrol text  idtext "Instructions" instructions 24 13 /title

      gcontrol panel gplot "MAP" 400 400
      gcontrol line
      gcontrol button pop   "" "Pop" 0 /nostate /nodepress

      plot/id=gplot/msgid=main ^{datDir}.world.prm
      set this.timer(0) 0.25
    pipe off

  endif
endmacro

!******************************************************************************!
! Main process message for this macro. Should be right after the ENDMACRO.
!******************************************************************************!
procedure processMessage m:msg
  if msg.name eqs "MAIN" then
    assert/text="^reg.main.name: User indicated tests" msg.data eqss "PASS"
    pipe stop

  elseif msg.name eqs "POP" then
    message send gplot ,, "POP" -1 "TOGGLE"
    if reg.gplot.isPopped()
      set gc.pop.items "Pop"
    else
      set gc.pop.items "Push"
    endif

  elseif msg.name eqs "TIMER"
    if reg.gplot.isPopped()
      set gc.pop.items "Push"
    else
      set gc.pop.items "Pop"
    endif

  else
    !say "Unhandled message name: ^msg.name from fid: ^msg.fid data: ^msg.data"
  endif
return

!******************************************************************************!
! If an unexpected exception is caught, mark test as failed, unless it is expected
!******************************************************************************!
procedure processException m:emsg
  if expectedException REXISTS then
    assert/text="^reg.main.name: Expected ERROR starts with: ^{expectedException}" expectedException EQSS emsg.data.message
    remove expectedException
  else
    assert/text="^reg.main.name: Caught unexpected exception ^{emsg.data}" "FALSE" isTrue
    if "Trace" SUBS ENV.DEBUG then invoke ,, emsg.data.printStackTrace()
  endif
return

!******************************************************************************!
! Set the dat directory
!******************************************************************************!
procedure setDatDir
  invoke nxmMajor env.nmversion.subString(0,1)
  invoke major java.lang.Integer.valueOf(nxmMajor)
  if major GE 4 then
    invoke s:datDir           nxm.sys.test.DatLocator.getDatDirLocation()
    invoke s:datDirSlash      nxm.sys.test.DatLocator.getDatDirSlashLocation()
    invoke z:sysDatFull       nxm.sys.test.DatLocator.sysDatFull()
    invoke z:sysTestDatExists nxm.sys.test.DatLocator.sysTestDatExists()
  else
    set s:datDir           "nxm.sys.dat"
    set s:datDirSlash      "nxm/sys/dat"
    set z:sysDatFull       true
    set z:sysTestDatExists false
  endif
return
