!******************************************************************************!
! Test the functionality of AutoSelectMode for Pixel and GreatArc
!
!
! @bug      NXM-3511 AutoSelectMode
!           NXM-3522 LayerT5 select point does not work in GEODETIC view when
!                    points are not on the surface of the earth
! @since    3.9.3
! @author:  Kevin Esterheld
!******************************************************************************!
startmacro
  switch INTERACTIVE interAct GET DEF=TRUE  SDEF=TRUE  ! for normal interactive test(s)
  switch BASELINE    baseline GET DEF=FALSE SDEF=TRUE  ! for defects or more obscure test case(s)

  call setDatDir

  if interAct then
    set instructions "Top Plot - SV3 plot using AutoSelectMode=Pixel\n\n&
                      Bottom Plot - SV3 plot using AutoSelectMode=GreatArc\n\n&
                      1) Click to select points\n&
                      Top: will select the closest point\n&
                      Bottom: will now auto-switch to PIXEL\n\n&
                      2) Hold down ctrl and click on a point.\n&
                      Top: should get popup of point data\n&
                      Bottom: will now auto-switch to PIXEL"

    pipe on
      panel/msgid=MAIN/setup/controls=gc
      gcontrol label macro "Test MACRO"
      gcontrol menu  main "Exit with Status =" "PASS,FAIL" TABLE={ItemColors={PASS="GREEN",FAIL="RED"}} /tleft

      gcontrol text  idtext "Instructions" instructions 24 20 /title


      plot/id=plot1 ^{datDir}.world.prm|^{datDir}.sv3.prm{layer={AutoselectEnable="CLICK",AutoSelectMode="Pixel",COLOR=BLUE, SELECTCOLOR=GREEN}} view=GEO 

      plot/id=plot2 ^{datDir}.world.prm|^{datDir}.sv3.prm{layer={AutoselectEnable="CLICK",AutoSelectMode="GreatArc",COLOR=BLUE, SELECTCOLOR=GREEN}} view=geo
    pipe off

  endif
endmacro

!******************************************************************************!
! Main process message for this macro. Should be right after the ENDMACRO.
!******************************************************************************!
procedure processMessage m:msg
  if msg.name eqs "MAIN" then
    assert/text="^reg.main.name: User indicated tests" msg.data eqss "PASS"
    pipe stop
  else
    say "Unhandled message name: ^msg.name from fid: ^msg.fid data: ^msg.data"
  endif
return

!******************************************************************************!
! If an unexpected exception is caught, mark test as failed, unless it is expected
!******************************************************************************!
procedure processException m:emsg
  if expectedException REXISTS then
    assert/text="^reg.main.name: Expected ERROR starts with: ^{expectedException}" expectedException EQSS emsg.data.message
    remove expectedException
  else
    assert/text="^reg.main.name: Caught unexpected exception ^{emsg.data}" "FALSE" isTrue
    if "Trace" SUBS ENV.DEBUG then invoke ,, emsg.data.printStackTrace()
  endif
return

!******************************************************************************!
! Set the dat directory
!******************************************************************************!
procedure setDatDir
  invoke nxmMajor env.nmversion.subString(0,1)
  invoke major java.lang.Integer.valueOf(nxmMajor)
  if major GE 4 then
    invoke s:datDir           nxm.sys.test.DatLocator.getDatDirLocation()
    invoke s:datDirSlash      nxm.sys.test.DatLocator.getDatDirSlashLocation()
    invoke z:sysDatFull       nxm.sys.test.DatLocator.sysDatFull()
    invoke z:sysTestDatExists nxm.sys.test.DatLocator.sysTestDatExists()
  else
    set s:datDir           "nxm.sys.dat"
    set s:datDirSlash      "nxm/sys/dat"
    set z:sysDatFull       true
    set z:sysTestDatExists false
  endif
return
