!------------------------------------------------------------------------------!
! Tests for LIST2 command.
!
!   Author : J. Czechowski IV
!------------------------------------------------------------------------------!
startmacro/tsetup=nxm.sys.test.test_list2_setup.tbl
  switch INTERACTIVE  interAct     GET DEF=TRUE
  switch standalone   standalone   GET DEF=TRUE
  switch COREGRAPHICS coregraphics GET DEF=FALSE SDEF=TRUE  ! for a quick check of graphics - more extreme tests - since 3.8.1

  call setDatDir

  if interAct or coregraphics then
    set instructions "These settings control the font used for the values in the table. &
                      Change the FontSize, FontStyle, and RowHeight to verify the changes. &
                      When RowHeight=-1, the height of the row should be automatically &
                      set to match the font size (note that RowHeight=0 is invalid &
                      and is ignored by this macro). "


    pipe init
      panel/msgid=MAIN/id=panel/controls=gc
      list2/grid=on/msgid=MAIN/id=idlist ^{datDir}.testxy3000.prm
      if standalone isTrue then
        gcontrol label  macro   "MACRO"
        gcontrol menu MAIN "Exit with Status = " "PASS,FAIL" /tleft
        set gc.MAIN.itemColors {PASS=GREEN,FAIL=RED}
      endif
      gcontrol text   idtext    "Instructions" "^{instructions}" 24 14 /title
      gcontrol label  listTest   "Options" AlwaysOpen
      gcontrol fval   fontSize  "FontSize  :"  12 8 32 1
      gcontrol button fontStyle "FontStyle :" "Bold,Italic" "" /FLAGS="Toggle|ChkBox|TLeft|NoState"
      gcontrol lval   rowHeight "RowHeight :"  -1 -1 36 1

    pipe off
  endif
endmacro

!------------------------------------------------------------------------------!
procedure processMessage m:msg
!
! Procedure for handling all messages
!
  if msg.name EQS "MAIN" then
    if msg.data EQS "EXIT" then
      pipe stop
    else
      assert/text="LIST2 tests" "PASS" SUBS msg.data
      pipe stop
    endif
  elseif msg.fid EQS "IDLIST" then
    !say "Got ^msg.name from ^msg.fid"
  
  elseif msg.name EQS "FONTSIZE" then
    invoke ,, reg.idlist.updateTemplate({_GLOBAL_={FONTSIZE=^{msg.data}}})

  elseif msg.name EQS "FONTSTYLE" then
    invoke ,, reg.idlist.updateTemplate({_GLOBAL_={FONTSTYLE=^{gc.fontStyle.value}}})

  elseif msg.name EQS "ROWHEIGHT" then
    if msg.data neq 0 then
      invoke ,, reg.idlist.updateTemplate({_GLOBAL_={ROWHEIGHT=^{msg.data}}})
    endif

  else
    say "Unhandled messagename: ^msg.name from fid: ^msg.fid data: ^msg.data"
  endif


return

!******************************************************************************!
! Set the dat directory
!******************************************************************************!
procedure setDatDir
  invoke nxmMajor env.nmversion.subString(0,1)
  invoke major java.lang.Integer.valueOf(nxmMajor)
  if major GE 4 then
    invoke s:datDir           nxm.sys.test.DatLocator.getDatDirLocation()
    invoke s:datDirSlash      nxm.sys.test.DatLocator.getDatDirSlashLocation()
    invoke z:sysDatFull       nxm.sys.test.DatLocator.sysDatFull()
    invoke z:sysTestDatExists nxm.sys.test.DatLocator.sysTestDatExists()
  else
    set s:datDir           "nxm.sys.dat"
    set s:datDirSlash      "nxm/sys/dat"
    set z:sysDatFull       true
    set z:sysTestDatExists false
  endif
return
