!------------------------------------------------------------------------------!
! Tests for LIST2 command.
!
!   Author : J. Czechowski IV
!------------------------------------------------------------------------------!
startmacro/tsetup=nxm.sys.test.test_list2_setup.tbl s:autoSelect[false]
  switch INTERACTIVE  interAct     GET DEF=TRUE
  switch standalone   standalone   GET DEF=TRUE
  switch COREGRAPHICS coregraphics GET DEF=FALSE SDEF=TRUE  ! for a quick check of graphics - more extreme tests - since 3.8.1

  call setDatDir

  if interAct OR coreGraphics then
    set instr {}
    set instr.Single           "Clicking a CELL selects it. CTRL+CLICK and SHIFT+CLICK are same as CLICK."
    set instr.SingleInterval   "Clicking a CELL selects it. SHIFT+CLICK should select interval &
                                (last click to current), CTRL+CLICK is same as CLICK."
    set instr.MultipleInterval "Clicking a CELL selects it. SHIFT+CLICK should select interval &
                                (last click to current), CTRL+CLICK adds to selection."

    set fname ^{datDir}.testxy3000.prm
    set templ {_GLOBAL_={SORTENABLED=F}}
    invoke selectModeList nxm.sys.inc.ListInterface.selectModeList

    pipe init
      panel/msgid=MAIN/id=panel/controls=gc
      list2/grid=on/msgid=MAIN/id=idlist fname templ /LEGACY
      set reg.idlist.selectMode "Single"
      if standalone isTrue then
        gcontrol label  macro   "MACRO"
        gcontrol menu MAIN "Exit with Status = " "PASS,FAIL" /tleft
        set gc.MAIN.itemColors {PASS=GREEN,FAIL=RED}
      endif

      gcontrol text   idtext     "Instructions" "<initializing>" 24 10 /title
      gcontrol label  listTest   "Options" AlwaysOpen
      gcontrol choice selectMode "SelectMode:"  "^selectModeList" reg.idlist.selectMode /tleft
      set gc.idtext.value "^{instr.^{reg.idlist.selectMode}}"

    pipe off

  endif
endmacro

!------------------------------------------------------------------------------!
procedure processMessage m:msg
  if msg.name EQS "MAIN" then
    if msg.data EQS "EXIT" then
      pipe stop
    else
      assert/text="LIST2 tests" "PASS" SUBS msg.data
      pipe stop
    endif
  elseif msg.fid EQS "IDLIST" then
    !say "Got ^msg.name from ^msg.fid"

  elseif msg.name EQS "SELECTMODE" then
    set reg.idlist.selectMode   msg.data
    set gc.idtext.value "^{instr.^{reg.idlist.selectMode}}"

  else
    say "Unhandled messagename: ^msg.name from fid: ^msg.fid data: ^msg.data"
  endif

return

!******************************************************************************!
! Set the dat directory
!******************************************************************************!
procedure setDatDir
  invoke nxmMajor env.nmversion.subString(0,1)
  invoke major java.lang.Integer.valueOf(nxmMajor)
  if major GE 4 then
    invoke s:datDir           nxm.sys.test.DatLocator.getDatDirLocation()
    invoke s:datDirSlash      nxm.sys.test.DatLocator.getDatDirSlashLocation()
    invoke z:sysDatFull       nxm.sys.test.DatLocator.sysDatFull()
    invoke z:sysTestDatExists nxm.sys.test.DatLocator.sysTestDatExists()
  else
    set s:datDir           "nxm.sys.dat"
    set s:datDirSlash      "nxm/sys/dat"
    set z:sysDatFull       true
    set z:sysTestDatExists false
  endif
return
